استند کارت فراری با آردوینو و سنسور التراسونیک

/* Main Arduino Code
Used to control LEDs, Photoresisor Sensors, Servo Motor
and to process signals received from the Ultrasonic sensor.
*/
#include <Servo.h>
// Define Sensor and Actuator Pins
const int AphotoPIN = A0;
const int BphotoPIN = A1;
const int RledPIN = 10;
const int GledPIN = 11;
const int AservoPIN = 5;
const int dataPIN = 12;
// Servo Motor Setup
Servo servoA;
int pos = 0;
// Sensor Data from Arduino Controlling Ultrasonic Sensor
int sensor_output = 0;
int DATA = 0;
// Variables for Misleading Sensors
int sensorValueA = 0; // Photoresistor Values
int sensorValueB = 0;
int dummyA = 0; // Target Value of Photoresistor
int dummyB = 0;
int dummyAhigh = 0; // Bounds on Acceptable Target Values
int dummyAlow = 0;
int dummyBhigh = 0;
int dummyBlow = 0;
boolean dummyAtest = false; // Test for Correct Photoresistor Value
boolean dummyBtest = false;
int seed = 0; // Random Sensor Variation
// Variables for Passive Animations
boolean passive_animation = false;
int passive_TIMER = 0;
int passive_SELECT = 0;
// Variables for when Motion is Detected
boolean motion_detected = false;
int trigger_length = 0;
boolean motion_active = false;
void setup() {
// Randomizer for Misleading Sensors and Passive Animations:
seed = analogRead(A2);
randomSeed(seed);
// Define Input/Output Pins:
pinMode(RledPIN, OUTPUT);
pinMode(GledPIN, OUTPUT);
pinMode(dataPIN, INPUT);
servoA.attach(AservoPIN);
// Move Motor to Starting Position:
servoA.write(95);
// Define Misleading Sensors Values:
dummyA = random(30, 70);
dummyB = random(30, 70);
dummyAlow = dummyA - 10;
dummyAhigh = dummyA + 10;
dummyBlow = dummyB - 10;
dummyBhigh = dummyB + 10;
// Serial.begin (9600); (For Troubleshooting)
// 'Warm Up' Delay for Proper Operation Confirmation:
delay(2500);
}
void loop() {
// Randomizer for Passive Animations:
seed = analogRead(A2);
randomSeed(seed);
// Check if a Passive Animation should be played (and which one):
if (passive_animation == true) {
if (passive_SELECT == 1) {
passive_1();
} else if (passive_SELECT == 2) {
passive_2();
}
}
/* When no motion is present, start a count down to a
Passive Animation Activation, after 15 seconds of no
motion, play a random Passive Animation: */
if (motion_detected == false) {
passive_TIMER += 1;
if (passive_TIMER == 300) {
passive_SELECT = random(1, 3);
passive_animation = true;
passive_TIMER = 0;
}
}
/* When Motion is detected: run Active Animation, start a
count up on how long motion is continuously detected and
reset the Passive Animation Timer: */
if (motion_detected == true) {
sensor_triggered();
trigger_length += 1;
passive_TIMER = 0;
/* Play small Animation if motion is continuously detected
for 10 seconds: */
if (trigger_length >= 200) {
servoA.write(75);
delay(500);
servoA.write(80);
trigger_length = 0;
}
// When motion is no longer detected, reset motor position:
} else if (motion_active == true) {
servoA.write(95);
motion_active = false;
}
/* Check Output from Arduino running Ultrasonic Sensor for a
signal indicating motion: */
sensor_output = digitalRead(dataPIN);
if(sensor_output == HIGH) {
motion_detected = true;
} else {
motion_detected = false;
}
/* Run Misleading Sensors Animation if no Motion is detected
and both sensors are inside their range: */
dummy_sensors();
if (motion_detected == false && passive_animation == false) {
if(dummyAtest == true && dummyBtest == true) {
servoA.write(75);
delay(750);
servoA.write(95);
delay(750);
servoA.write(75);
delay(750);
servoA.write(95);
delay(750);
}
}
delay(50); // Delay for Tick Speed (20 Ticks/Second)
}
// Activate Motor (Push Spring Down) when motion detected:
void sensor_triggered() {
servoA.write(75);
passive_TIMER = 0;
motion_active = true;
}
// Run Misleading Sensors:
void dummy_sensors() {
// Check and Remap (0-100) the Photoresistor Sensor Values:
sensorValueA = analogRead(AphotoPIN);
sensorValueB = analogRead(BphotoPIN);
sensorValueA = map(sensorValueA, 0, 700, 0, 100);
sensorValueB = map(sensorValueB, 0, 700, 0, 100);
constrain(sensorValueA, 0, 100);
constrain(sensorValueB, 0, 100);
/* Check if the Photoresistor Sensor Values are within the
desired range (turn LED on if that one is): */
if (sensorValueA >= dummyAlow && sensorValueA <= dummyAhigh) {
digitalWrite(RledPIN, HIGH);
dummyAtest = true;
} else {
digitalWrite(RledPIN, LOW);
dummyBtest = false;
}
if (sensorValueB >= dummyAlow && sensorValueB <= dummyBhigh) {
digitalWrite(GledPIN, HIGH);
dummyBtest = true;
} else {
digitalWrite(GledPIN, LOW);
dummyBtest = false;
}
}
// First Passive Animation (Drop, Wait, Lift Back Up):
void passive_1() {
if (passive_animation == true) {
for (int pos = 95; pos >= 75; pos -= 1) { // Push Lever Down
servoA.write(pos);
delay(20);
}
delay(1500); // Wait
for (int pos = 75; pos <= 95; pos += 1) { // Lift Lever
servoA.write(pos);
delay(20);
}
// Reset Passive Animation
passive_animation = false;
passive_SELECT = 0;
}
}
/* Second Passive Animation (Quick Drop, Wait, Slow Lift
Halfway, Wait, Lift Other Half) */
void passive_2() {
if (passive_animation == true) {
for (int pos = 95; pos >= 75; pos -= 1) { // Quick Push Lever Down
servoA.write(pos);
}
delay(2500); // Wait
for (int pos = 75; pos <= 85; pos += 1) { // Slowly Lift Lever Halfway
servoA.write(pos);
delay(50);
}
delay(2500); // Wait
for (int pos = 85; pos <= 95; pos += 1) { // Lift Lever Remain Distance
servoA.write(pos);
delay(20);
}
passive_animation = false;
passive_SELECT = 0;
}
}

/* Arduino Controlling Ultrasonic Sensor
Utilizing a second Arduino for the sensor pulses
allows each controller to focus on processing its tasks
more efficiently (the nanosecond delays in the ultrasonic
sensor code do no interfere with operations of the main code).
*/
// Sensor and Connector Pins
const int trigPIN = 10;
const int echoPIN = 5;
const int dataPIN = 8;
// Variables Used in Distance Calculation
float dur = 0;
float dist = 0;
void setup() {
// Sensor and Connector Pin Setup
pinMode(trigPIN, OUTPUT);
pinMode(echoPIN, INPUT);
pinMode(dataPIN, OUTPUT);
// Serial.begin(9600); (For Troubleshooting)
}
void loop() {
digitalWrite(trigPIN, LOW); // Reset the Sensors
delayMicroseconds(2);
digitalWrite(trigPIN, HIGH); // Send Ultrasonic Signal
delayMicroseconds(10);
digitalWrite(trigPIN, LOW); // Stop Ultrasonic Signal
dur = pulseIn(echoPIN, HIGH); // Log Time Till Signal Returns
dist = (dur*.0343)/2; // Compute Distance from Time
/* Send signal to Main Arduino if something
is detected within 30cm: */
if (dist <= 30 && dist >= 1) {
digitalWrite(dataPIN, HIGH);
} else {
digitalWrite(dataPIN, LOW);
}
delay(100);
// Serial.println(dist); (For Troubleshooting)
}